Como ter um pegajoso cabeçalho para um GridLayout em um Flickable

É um pouco hacky, mas eu achei uma solução.

Primeiro, criar o "fictício" cabeçalhos que são Items. Você pode fazer o ajuste de suas Layout.minimalWidth para ser a largura do texto do cabeçalho, se você precisa.

Em seguida, em um Item antes de o Flickable, criar seu cabeçalho, verifique se ele está alinhado horizontalmente com a grade, e a posição os elementos usando o x valores do cabeçalho.

Finalmente, defina uma margem negativa Flickable para remover o estranho linha adicionada pelo fictício cabeçalhos.

Eu também tentei usar fillWidth: true em manequins e, em seguida, definindo o width de cada cabeçalho de itens, mas a desvantagem é que ele modifica a tabela de largura de coluna.

import QtQuick 2.0
import QtQuick.Layouts 1.12

ColumnLayout {
    width: 200
    height: 200

    // Header
    Item {
        Layout.minimumHeight: childrenRect.height
        Layout.fillWidth: true
        Text {
            id: header0
            x: headerDummy0.x
            anchors.top: parent.top
            text: "Header 0"
        }
        Text {
            id: header1
            x: headerDummy1.x
            anchors.top: parent.top
            text: "Header 1"
        }
        Text {
            id: header2
            x: headerDummy2.x
            anchors.top: parent.top
            text: "Header 2"
        }
    }

    Flickable {
        Layout.fillWidth: true
        Layout.preferredHeight: 200
        contentWidth: width
        contentHeight: grid.height
        clip: true
        // Eliminate the first row, which are the dummies
        topMargin: - grid.rowSpacing

        GridLayout {
            id: grid
            columns: 3
            rowSpacing: 50
            columnSpacing: 10

            function reparentChildren(source, target) {
                while (source.children.length) {
                    source.children[0].parent = target;
                }
            }

            // Header dummies
            Item {
                id: headerDummy0
                Layout.minimumWidth: header0.implicitWidth
            }
            Item {
                id: headerDummy1
                Layout.minimumWidth: header1.implicitWidth
            }
            Item {
                id: headerDummy2
                Layout.minimumWidth: header2.implicitWidth
            }

            // Data
            Repeater {
                model: 50

                Item {
                    Component.onCompleted: grid.reparentChildren(this, grid)
                    Text {
                        text: "Column 0, %1".arg(modelData)
                    }
                    Text {
                        text: "Column 1, %1".arg(modelData)
                    }
                    Text {
                        text: "Column 2, %1".arg(modelData)
                    }
                }
            }
        }
    }
}